yeolyi.com성열의 컴퓨터공학

집 나간 함수가 돌아오는 법

함수

초안아직 검토하지 않은 글이라 틀린 곳이 있을 수 있습니다.

스택 포인터까지 오며 기계는 CALL과 RET로 함수를 어디서든 부를 수 있게 됐습니다. 그런데 지금까지 우리가 쓴 C 프로그램에는 main 하나뿐입니다. 함수를 따로 만들어 부르는 코드는 어떤 명령어로 옮기면 될까요?

함수 정의와 return

C에서 함수는 이렇게 만듭니다. 우리가 써 온 main도 함수입니다.

함수를 부르는 쪽을 호출자(caller), 불리는 함수를 피호출자(callee)라 합니다. short 인자 하나가 레지스터 둘을 차지하니 인자를 레지스터로 넘기면 금방 모자랍니다. 그래서 호출자는 넘길 값을 스택에 PUSH하고 CALL합니다. 위 바이트를 먼저 넣어 메모리에서도 아래 바이트가 앞 주소에 옵니다. 피호출자는 돌려줄 값을 R1:R0에 두고 RET합니다.

스택에서 인자 읽기

피호출자에게 인자는 돌아올 주소 바로 위, SP + 1번 주소부터 있습니다. 이 주소를 계산하려면 SP를 레지스터로 옮겨야 하니 명령어 둘을 더합니다. 분량상 하드웨어 구현은 살펴보지 않습니다.

피호출자는 MOVE R3, SP로 얻은 주소에 1을 더해 인자를 읽습니다. 돌아온 호출자는 ADDI SP, 2로 넣었던 인자 두 칸을 한 번에 걷어 냅니다.

C
1short twice(short x) {
2 return x + x;
3}
4
5int main(void) {
6 short a = twice(3);
7 short b = twice(a);
8}
어셈블리어
0–1LDI R0, 3
2–3LDI R1, 0
4–5PUSH R1
6–7PUSH R0
8–9CALL twice
10–11ADDI SP, 2
12–13MOVE R2, R0
14–15MOVE R3, R1
16–17MOVE R0, R2
18–19MOVE R1, R3
20–21PUSH R1
22–23PUSH R0
24–25CALL twice
26–27ADDI SP, 2
28–29STORE R0, b
30–31STORE R1, b+1
32–33HALT
34–35twice: MOVE R3, SP
36–37ADDI R3, 1
38–39LOAD R2, [R3]
40–41ADDI R3, 1
42–43LOAD R3, [R3]
44–45MOVE R0, R2
46–47MOVE R1, R3
48–49ADD R0, R2
50–51ADC R1, R3
52–53RET
54–55b: 0, 0
R0 0R1 0R2 0R3 0SP 0Z 0C 0
a@R3:R2 0b@54 0
스택
비어 있음

6번 줄과 1번 줄에 차례로 커서를 두고 인자가 스택을 거쳐 R3:R2로 가는 것을 따라가 봅시다.

함수 안에서 또 함수를 불러도, 돌아올 주소가 스택에 쌓이니 제자리로 돌아옵니다.

C
1short add1(short x) {
2 return x + 1;
3}
4
5int add2(short x) {
6 return add1(add1(x));
7}
8
9int main(void) {
10 short r = add2(5);
11}
어셈블리어
0–1LDI R0, 5
2–3LDI R1, 0
4–5PUSH R1
6–7PUSH R0
8–9CALL add2
10–11ADDI SP, 2
12–13MOVE R2, R0
14–15MOVE R3, R1
16–17HALT
18–19add1: MOVE R3, SP
20–21ADDI R3, 1
22–23LOAD R2, [R3]
24–25ADDI R3, 1
26–27LOAD R3, [R3]
28–29MOVE R0, R2
30–31MOVE R1, R3
32–33ADDI R0, 1
34–35ADCI R1, 0
36–37RET
38–39add2: MOVE R3, SP
40–41ADDI R3, 1
42–43LOAD R2, [R3]
44–45ADDI R3, 1
46–47LOAD R3, [R3]
48–49MOVE R0, R2
50–51MOVE R1, R3
52–53PUSH R1
54–55PUSH R0
56–57CALL add1
58–59ADDI SP, 2
60–61PUSH R1
62–63PUSH R0
64–65CALL add1
66–67ADDI SP, 2
68–69RET
R0 0R1 0R2 0R3 0SP 0Z 0C 0
r@R3:R2 0
스택
비어 있음

6번 줄에 커서를 두고 봅시다. 안쪽 add1의 결과가 R1:R0으로 돌아오니 그대로 PUSH해 바깥 add1에 넘깁니다.

덮어써지는 변수

호출자와 피호출자 모두 본문을 실행하는 데 같은 R0~R3을 씁니다. 그러면 호출자가 레지스터에 둔 변수는 어떻게 될까요?

C
1short f(short x) {
2 return x + (x + (x + 1));
3}
4
5int main(void) {
6 short a = 5;
7 short b = f(1) + a;
8}
어셈블리어
0–1LDI R2, 5
2–3LDI R3, 0
4–5LDI R0, 1
6–7LDI R1, 0
8–9PUSH R1
10–11PUSH R0
12–13CALL f
14–15ADDI SP, 2
16–17ADD R0, R2
18–19ADC R1, R3
20–21STORE R0, b
22–23STORE R1, b+1
24–25HALT
26–27f: MOVE R3, SP
28–29ADDI R3, 1
30–31LOAD R2, [R3]
32–33ADDI R3, 1
34–35LOAD R3, [R3]
36–37MOVE R0, R2
38–39MOVE R1, R3
40–41ADDI R0, 1
42–43ADCI R1, 0
44–45ADD R0, R2
46–47ADC R1, R3
48–49ADD R0, R2
50–51ADC R1, R3
52–53RET
54–55b: 0, 0
R0 0R1 0R2 0R3 0SP 0Z 0C 0
a@R3:R2 0b@54 0
스택
비어 있음

f(1)은 4라 b는 9여야 하지만, f가 인자를 읽느라 a가 든 R3:R2를 덮어써 5가 됩니다.

마무리

다음 글에서는 호출자의 변수를 지키는 스택 프레임을 다룹니다.

도전 문제

아래 프로그램을 실행하는 동안 스택은 최대 몇 칸까지 쌓일까요? 숫자로 답하세요.

short add1(short x) {
  return x + 1;
}

short add2(short x) {
  return add1(add1(x));
}

short add4(short x) {
  return add2(add2(x));
}

int main(void) {
  short r = add4(0);
}